Студент группы специальность Фамилия Имя Отчество




Yüklə 47.85 Kb.
tarix28.02.2016
ölçüsü47.85 Kb.
З А Д А Н И Е № 18

по курсовому проектированию по дисциплине Автоматизированное проектирование радиоэлектронных устройств


Студент группы специальность ______________

Фамилия Имя Отчество ________

Руководитель курсового проектирования ._ ______________________

Срок проектирования с по _________ _______________

1. Тема курсового проекта Моделирование и анализ УМЗЧ без общей отрицательной связи с помощью пакета программ OrCAD PSpice ____________________ ______________ __________________________ 2. Содержание проекта (какие графические работы и расчеты должны быть выполнены)

Чертеж схемы; загрузочный файл схемы; исправление ошибок в схеме; анализ по переменному току; временной анализ; анализ шумов; анализ Фурье; статистический анализ .

__________ ___ ____________________________________

3. Особые дополнительные сведения .

Технические характеристики УМЗЧ .

Полоса пропускания 10Гц-63кГц

Мощность на нагрузке 4 Ом 25Вт

Коэффициент гармоник при Рвых = 12,5Вт на частоте 1кГц 0,08%

Номинальное входное напряжение 2В

Входное сопротивление 47кОм

Также рассмотреть влияние таких факторов как температура и разброс значений сопротивлений резисторов на параметры и характеристики схемы .

Схема УМ представлена в Приложении1 .

Модели используемых элементов представлены в Приложении2 .

Пояснения для самоконтроля представлены в Приложении3 .

.

.

.

.

.

.

.

.

.

.

.

.

.

4. План выполнения курсового проекта:

Наименование элементов проектной работы

Сроки

Примечание

Отметка о выполнении




































5. Курсовое проектирование закончено ________________________________________

6. Оценка проекта __________________________________________________________
Руководитель______________________

ПРИЛОЖЕНИЕ1



Рис. 1. Схема усилителя.

ПРИЛОЖЕНИЕ 2
.model KT502a pnp(Is=3.306f Xti=3 eg=1.11 Vaf=86.3 Bf=153.6 Ise=3.306e-15 nf=1

+ Ne=1.36 ise=3.306f Ikf=2.47 var=40 Xtb=1.5 Br=3.375 Isc=33.2f Nc=2 rbm=23.2

+ Ikr=0.85 Rb=23.2 Rc=1.345 Cjc=18.71p mje=0.33 Mjc=.31 Vjc=.69 nr=1

+ Cje=30.64p Vje=.69 Tr=58.87n Tf=267.9e-12 Itf=0.785 Xtf=2 Vtf=65)

.model KT503a npn(Is=98.35f Xti=3 Eg=1.11 Vaf=123.5 Bf=1.58k Ise=1.164p

+ Ne=1.356 Ikf=0.2244 Xtb=1.5 Br=0.3431 Isc=1.123p Nc=2 rbm=40.7

+ Ikr=1.52 Rb=40.7 Rc=0.17 Cjc=14.6p Nf=1 nr=1 vjc=0.75 mjc=0.33 fc=0.5

+ Cje=56.2p Vje=.69 Tr=254.8n Tf=281.9p Itf=1.63 Xtf=2 Vtf=40)

.model ks510 d(is=7.3p n=1.35 rs=5.8 cjo=1.12p tt=250n vj=.8

+bv=8 ibv=5e-6)

.model kt825a pnp(is=6.974p bf=30 br=2.949 ise=902.5p ikf=4.029

+ ikr=0 ne=1.941 nc=2 vaf=20 rc=0.08 re=0.06 rb=0.3

+ tf=39.11n tr=971.7n xtf=2 vtf=10 itf=20 cje=569.1p

+ vje=0.75 mje=0.33 cjc=276p vjc=0.75 mjc=0.33 fc=0.5

+ eg=1.11 xtb=1.5 xti=3)

.model kt827a npn(is=974.4f xti=3 eg=1.11 vaf=50 bf=70 ne=1.941 ise=902.5p

+ ikf=4.029 xtb=1.5 br=2.949 nc=2 isc=0 ikr=0 rc=0.1 cjc=276p vjc=0.75

+ mjc=0.3333 fc=0.5 cje=569.1p vje=0.75 mje=0.33333

+ tr=971.7n tf=39.11n itf=20 vtf=10 xtf=2 rb=0.42 re=0.116)
ПРИЛОЖЕНИЕ 3

После того, как вы создали загрузочный файл, если вы все сделали правильно, то при проведения анализа .ОР выходном файле вы можете посмотреть информацию о рабочей точке, где указаны напряжения VOLTAGE в узлах схемы NODE. Полученные вами результаты должны приблизительно соответствовать приведенным ниже.

**** SMALL SIGNAL BIAS SOLUTION TEMPERATURE = 27.000 DEG C

NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE NODE VOLTAGE

( 1) 43.3920 ( 2) 21.2160 ( 3) 0.0000 ( 4) 0.0000

( 5) 20.5360 ( 6) 20.5360 ( 7) 19.8550 ( 8) 20.6040

( 9) 20.5790 ( 10) 20.5530 ( 11) 43.1190 ( 12) 42.4320

( 13) 20.5790 ( 14) 20.5790 ( 15) 20.5790 ( 16) .8634

( 17) 43.1380 ( 18) 26.4010 ( 19) 21.7360 ( 20) 18.2300

( 21) .2435 ( 22) 45.0000 ( 23) 25.8020 ( 24) 25.8020

( 25) 23.9610 ( 26) 23.2510 ( 27) 22.0580 ( 28) 21.3930

( 29) 20.8530 ( 30) 20.0640 ( 31) 18.9020 ( 32) 18.9020

( 33) 22.6480 ( 34) 22.2700 ( 35) 21.6580 ( 36) 21.9640

( 37) 21.9640 ( 39) .2643 ( 100) 0.0000

После проведения АС анализа полученный график АЧХ должен иметь вид примерно как на рис 2.. Из этого графика можно сделать вывод, что схема не удовлетворяет условию ТЗ, так как в области верхних частот находится выброс приводящий к искажению сигналов. По этому, необходимо задать с помощью процедуры STEP PARAM изменение сопротивлений резисторов R24 и R25 от 100Ом до 1кОм с шагом 100Ом. Проведя моделирование повторно, вы получите несколько графиков зависимости АЧХ от сопротивлений резисторов R24 и R25, представленных на рис3. Вам необходимо подобрать такие сопротивления при которых график АЧХ будет выглядеть приблизительно как на рис4.

Рис2. АЧХ УМЗЧ (при R24 и R25 = 100Ом)



Рис3. АЧХ УМЗЧ (при различных значениях R24 и R25)


Рис3. АЧХ УМЗЧ(при правильных значениях R24 и R25)

*** VARIANT 18 ***
.OPT ACCT LIST NODE OPTS NOPAGE RELTOL=0.0001 tnom=27

.WIDTH OUT 80

.TEMP 27

*.OP


*.DC vin -0.25 0.25 0.5

*.tf v(100) vin

*.mc 10 ac v(100) ymax output=all

.AC oct 20 1 1MEG

.PARAM A=100

.STEP PARAM A 100 1K 100

*.TRAN/OP 0.1U 3m

*.NOISE V(100) VIN

*.FOUR 1K v(3) V(100)

*.dc dec res r10 (r) 0.1 10 20

.model r res(r=1)

*.model r cap(c=1)

.sens v(33)
vin 3 0 ac 2 sin(0 2 1k)

vcc 22 0 dc 45

c1 4 5 2U

r1 6 5 r 4.7k

c2 6 0 470p

c4 0 1 1U

c5 1 0 470u

r2 2 1 r 75k

r3 6 2 r 2.7k

r4 7 6 r 2.7k

r5 0 7 r 75k

q1 1 2 8 kt503a

r6 9 8 r 12

r7 10 9 r 12

r8 14 9 r 1.1k

q2 0 7 10 kt502a

r11 11 1 r 240

rg 3 4 r 600

q3 12 12 11 kt502a

c6 13 12 4.7u

r91 14 13 r 1.05k

r92 15 14 r 1.25k

c3 0 14 1500p

c7 16 15 4.7u

q5 16 16 39 kt503a

r13 0 39 r 240

r10 16 12 36K

r12 17 1 91

q4 18 12 17 kt502a

r15 19 18 9.1k

r17 20 19 9.1k

q6 20 16 21 kt503a

r14 0 21 91

r16 19 1 620

r18 0 19 620

r19 1 22 39

d 20 18 ks510

q7 22 18 23 kt503a

r20 25 23 1.5k

r21 24 23 68

c8 25 24 33p

q9 22 25 26 kt503a

q11 22 26 34 kt827a

q8 0 20 32 kt502a

r22 32 30 1.5k

r23 32 31 68

c9 31 30 33p

q10 0 30 29 kt502a

q12 0 29 35 kt825a

r24 27 26 {A}

r25 29 27 {A}

q13 25 33 27 kt503a

r26 33 26 2.4k

r27 37 33 3k

c10 37 27 10p

q14 30 28 27 kt502a

r29 28 27 3k

r28 29 28 2.4k

r30 37 34 0.15

r31 35 37 0.15

c12 37 100 40m

r32 36 37 13

c11 0 36 0.047u

r33 0 100 4

cn 0 100 1u

.model KT502a pnp(Is=3.306f Xti=3 eg=1.11 Vaf=86.3 Bf=153.6 Ise=3.306e-15 nf=1

+ Ne=1.36 ise=3.306f Ikf=2.47 var=40 Xtb=1.5 Br=3.375 Isc=33.2f Nc=2 rbm=23.2

+ Ikr=0.85 Rb=23.2 Rc=1.345 Cjc=18.71p mje=0.33 Mjc=.31 Vjc=.69 nr=1

+ Cje=30.64p Vje=.69 Tr=58.87n Tf=267.9e-12 Itf=0.785 Xtf=2 Vtf=65)

.model KT503a npn(Is=98.35f Xti=3 Eg=1.11 Vaf=123.5 Bf=1.58k Ise=1.164p

+ Ne=1.356 Ikf=0.2244 Xtb=1.5 Br=0.3431 Isc=1.123p Nc=2 rbm=40.7

+ Ikr=1.52 Rb=40.7 Rc=0.17 Cjc=14.6p Nf=1 nr=1 vjc=0.75 mjc=0.33 fc=0.5

+ Cje=56.2p Vje=.69 Tr=254.8n Tf=281.9p Itf=1.63 Xtf=2 Vtf=40)

.model ks510 d(is=7.3p n=1.35 rs=5.8 cjo=1.12p tt=250n vj=.8

+bv=8 ibv=5e-6)

.model kt825a pnp(is=6.974p bf=30 br=2.949 ise=902.5p ikf=4.029

+ ikr=0 ne=1.941 nc=2 vaf=20 rc=0.08 re=0.06 rb=0.3

+ tf=39.11n tr=971.7n xtf=2 vtf=10 itf=20 cje=569.1p

+ vje=0.75 mje=0.33 cjc=276p vjc=0.75 mjc=0.33 fc=0.5

+ eg=1.11 xtb=1.5 xti=3)

.model kt827a npn(is=974.4f xti=3 eg=1.11 vaf=50 bf=70 ne=1.941 ise=902.5p

+ ikf=4.029 xtb=1.5 br=2.949 nc=2 isc=0 ikr=0 rc=0.1 cjc=276p vjc=0.75

+ mjc=0.3333 fc=0.5 cje=569.1p vje=0.75 mje=0.33333

+ tr=971.7n tf=39.11n itf=20 vtf=10 xtf=2 rb=0.42 re=0.116)



.probe

.end


Verilənlər bazası müəlliflik hüququ ilə müdafiə olunur ©azrefs.org 2016
rəhbərliyinə müraciət

    Ana səhifə